Markers
*******

A marker is a Lisp object used to specify a position in a buffer relative to the surrounding text.  A marker changes its offset from the beginning of the buffer automatically whenever text is inserted or deleted, so that it stays with the two characters on either side of it.

Overview of Markers
===================

A marker specifies a buffer and a position in that buffer.  The marker can be used to represent a position in the functions that require one, just as an integer could be used.  See Positions, for a complete description of positions.

A marker has two attributes: the marker position, and the marker buffer.  The marker position is an integer which is equivalent (at the moment) to the marker as a position in that buffer; however, as text is inserted or deleted in the buffer, the marker is relocated, so that its integer equivalent changes.  The idea is that a marker positioned between two characters in a buffer will remain between those two characters despite any changes made to the contents of the buffer; thus, a marker's offset from the beginning of a buffer may change often during the life of the marker.

If the text around a marker is deleted, the marker is repositioned between the characters immediately before and after the deleted text.  If text is inserted at the position of a marker, the marker remains in front of the new text unless it is inserted with insert-before-markers (see Insertion).  When text is inserted or deleted somewhere before the marker position (not next to the marker), the marker moves back and forth with the two neighboring characters.

When a buffer is modified, all of its markers must be checked so that they can be relocated if necessary.  This slows processing in a buffer with a large number of markers.  For this reason, it is a good idea to make a marker point nowhere if you are sure you don't need it any more. Unreferenced markers will eventually be garbage collected, but until then will continue to be updated if they do point somewhere.

Because it is quite common to perform arithmetic operations on a marker position, most of the arithmetic operations (including + and -) accept markers as arguments.  In such cases, the current position of the marker is used.

Here are examples of creating markers, setting markers, and moving point to markers:

     ;; Make a new marker that initially does not point anywhere:
     (setq m1 (make-marker))
          => #<marker in no buffer>

     ;; Set m1 to point between the 100th and 101st characters
     ;;   in the current buffer:
     (set-marker m1 100)
          => #<marker at 100 in markers.texi>

     ;; Now insert one character at the beginning of the buffer:
     (goto-char (point-min))
          => 1
     (insert "Q")
          => nil

     ;; m1 is updated appropriately.
     m1
          => #<marker at 101 in markers.texi>

     ;; Two markers that point to the same position
     ;;   are not eq, but they are equal.
     (setq m2 (copy-marker m1))
          => #<marker at 101 in markers.texi>
     (eq m1 m2)
          => nil
     (equal m1 m2)
          => t

     ;; When you are finished using a marker, make it point nowhere.
     (set-marker m1 nil)
          => #<marker in no buffer>

Predicates on Markers
=====================

You can test an object to see whether it is a marker, or whether it is either an integer or a marker.  The latter test is useful when you are using the arithmetic functions that work with both markers and integers.

 -- Function: markerp object
     This function returns t if OBJECT is a marker, nil otherwise.  In particular, integers are not markers, even though many functions will accept either a marker or an integer.

 -- Function: integer-or-marker-p object
     This function returns t if OBJECT is an integer or a marker, nil otherwise.

 -- Function: number-or-marker-p object
     This function returns t if OBJECT is a number (of any type) or a marker, nil otherwise.

Functions That Create Markers
=============================

When you create a new marker, you can make it point nowhere, or point to the present position of point, or to the beginning or end of the accessible portion of the buffer, or to the same place as another given marker.

 -- Function: make-marker
     This functions returns a newly allocated marker that does not point anywhere.

          (make-marker)
               => #<marker in no buffer>

 -- Function: point-marker
     This function returns a new marker that points to the present position of point in the current buffer.  See Point.  For an example, see copy-marker, below.

 -- Function: point-min-marker
     This function returns a new marker that points to the beginning of the accessible portion of the buffer.  This will be the beginning of the buffer unless narrowing is in effect.  See Narrowing.

 -- Function: point-max-marker
     This function returns a new marker that points to the end of the accessible portion of the buffer.  This will be the end of the buffer unless narrowing is in effect.  See Narrowing.

     Here are examples of this function and point-min-marker, shown in a buffer containing a version of the source file for the text of this chapter.

          (point-min-marker)
               => #<marker at 1 in markers.texi>
          (point-max-marker)
               => #<marker at 15573 in markers.texi>

          (narrow-to-region 100 200)
               => nil

          (point-min-marker)
               => #<marker at 100 in markers.texi>

          (point-max-marker)
               => #<marker at 200 in markers.texi>

 -- Function: copy-marker marker-or-integer
     If passed a marker as its argument, copy-marker returns a new marker that points to the same place and the same buffer as does MARKER-OR-INTEGER.  If passed an integer as its argument, copy-marker returns a new marker that points to position MARKER-OR-INTEGER in the current buffer.

     If passed an argument that is an integer whose value is less than 1, copy-marker returns a new marker that points to the beginning of the current buffer.  If passed an argument that is an integer whose value is greater than the length of the buffer, then copy-marker returns a new marker that points to the end of the buffer.

     An error is signaled if MARKER is neither a marker nor an integer.

          (setq p (point-marker))
               => #<marker at 2139 in markers.texi>

          (setq q (copy-marker p))
               => #<marker at 2139 in markers.texi>

          (eq p q)
               => nil

          (equal p q)
               => t

          (copy-marker 0)
               => #<marker at 1 in markers.texi>

          (copy-marker 20000)
               => #<marker at 7572 in markers.texi>

Information from Markers
========================

This section describes the functions for accessing the components of a marker object.

 -- Function: marker-position marker
     This function returns the position that MARKER points to, or nil if it points nowhere.

 -- Function: marker-buffer marker
     This function returns the buffer that MARKER points into, or nil if it points nowhere.

          (setq m (make-marker))
               => #<marker in no buffer>

          (marker-position m)
               => nil

          (marker-buffer m)
               => nil

          (set-marker m 3770 (current-buffer))
               => #<marker at 3770 in markers.texi>

          (marker-buffer m)
               => #<buffer markers.texi>

          (marker-position m)
               => 3770

Two distinct markers will be found equal (even though not eq) to each other if they have the same position and buffer, or if they both point nowhere.

Changing Markers
================

This section describes how to change the position of an existing marker.  When you do this, be sure you know whether the marker is used outside of your program, and, if so, what effects will result from moving it---otherwise, confusing things may happen in other parts of Emacs.

 -- Function: set-marker marker position &optional buffer
     This function moves MARKER to POSITION in BUFFER.  If BUFFER is not provided, it defaults to the current buffer.

     If POSITION is less than 1, set-marker moves marker to the beginning of the buffer.  If the value of POSITION is greater than the size of the buffer, set-marker moves marker to the end of the buffer.  If POSITION is nil or a marker that points nowhere, then MARKER is set to point nowhere.

     The value returned is MARKER.

          (setq m (point-marker))
               => #<marker at 4714 in markers.texi>

          (set-marker m 55)
               => #<marker at 55 in markers.texi>

          (setq b (get-buffer "foo"))
               => #<buffer foo>

          (set-marker m 0 b)
               => #<marker at 1 in foo>

 -- Function: move-marker marker position &optional buffer
     This is another name for set-marker.

The Mark
========

A special marker in each buffer is designated the mark.  It records a position for the user for the sake of commands such as C-w and C-x TAB.  Lisp programs should set the mark only to values that have a potential use to the user, and never for their own internal purposes.  For example, the replace-regexp command sets the mark to the value of point before doing any replacements, because this enables the user to move back there conveniently after the replace is finished.

Many commands are designed so that when called interactively they operate on the text between point and the mark.  If you are writing such a command, don't examine the mark directly; instead, use interactive with the r specification.  This will provide the values of point and the mark as arguments to the command in an interactive call, but will permit other Lisp programs to specify arguments explicitly.  See Interactive Codes.

Each buffer has its own value of the mark that is independent of the value of the mark in other buffers.  When a buffer is created, the mark exists but does not point anywhere.  We consider this state as ``the absence of a mark in that buffer''.

Once the mark ``exists'' in a buffer, it normally never ceases to exist.  However, it may become inactive, if Transient Mark mode is enabled.  The variable mark-active, which is always local in all buffers, indicates whether the mark is active: non-nil means yes.  A command can request deactivation of the mark upon return to the editor command loop by setting deactivate-mark to a non-nil value (but this deactivation only follows if Transient Mark mode is enabled).

The main motivation for using Transient Mark mode is that this mode also enables highlighting of the region when the mark is active. See Emacs Display.

In addition to the mark, each buffer has a mark ring which is a list of markers that are the previous values of the mark.  When editing commands change the mark, they should normally save the old value of the mark on the mark ring.  The mark ring may contain no more than the maximum number of entries specified by the variable mark-ring-max; excess entries are discarded on a first-in-first-out basis.

 -- Function: mark &optional force
     This function returns the position of the current buffer's mark as an integer.

     Normally, if the mark is inactive mark signals an error. However, if FORCE is non-nil, then it returns the mark position anyway---or nil, if the mark is not yet set for this buffer.

 -- Function: mark-marker
     This function returns the current buffer's mark.  This is the very marker which records the mark location inside Emacs, not a copy.  Therefore, changing this marker's position will directly affect the position of the mark. Don't do it unless that is the effect you want.

          (setq m (mark-marker))
               => #<marker at 3420 in markers.texi>

          (set-marker m 100)
               => #<marker at 100 in markers.texi>

          (mark-marker)
               => #<marker at 100 in markers.texi>

     Like any marker, this marker can be set to point at any buffer you like. We don't recommend that you make it point at any buffer other than the one of which it is the mark.  If you do, it will yield perfectly consistent, if rather odd, results.

 -- Function: set-mark position
     This function sets the mark to POSITION, and activates the mark. The old value of the mark is not pushed onto the mark ring.

     Please note: use this function only if you want the user to see that the mark has moved, and you want the previous mark position to be lost.  Normally, when a new mark is set, the old one should go on the mark-ring.  For this reason, most applications should use push-mark and pop-mark, not set-mark.

     Novice Emacs Lisp programmers often try to use the mark for the wrong purposes.  The mark saves a location for the user's convenience.  An editing command should not alter the mark unless altering the mark is part of the user-level functionality of the command.  (And, in that case, this effect should be documented.)  To remember a location for internal use in the Lisp program, store it in a Lisp variable.  For example:

          (let ((beg (point)))
            (forward-line 1)
            (delete-region beg (point))).

 -- Variable: mark-ring
     The value of this buffer-local variable is the list of saved former marks of the current buffer, most recent first.

          mark-ring
          => (#<marker at 11050 in markers.texi>
              #<marker at 10832 in markers.texi>
              ...)

 -- User Option: mark-ring-max
     The value of this variable is the maximum size of mark-ring. If more marks than this are pushed onto the mark-ring, it discards marks on a first-in, first-out basis.

 -- Function: push-mark &optional position nomsg activate
     This function sets the current buffer's mark to POSITION, and pushes a copy of the previous mark onto mark-ring.  If POSITION is nil, then the value of point is used. push-mark returns nil.

     The function push-mark normally does not activate the mark.  To do that, specify t for the argument ACTIVATE.

     A Mark set message is displayed unless NOMSG is non-nil.

 -- Function: pop-mark
     This function pops off the top element of mark-ring and makes that mark become the buffer's actual mark.  This does not change the buffer's point, and does nothing if mark-ring is empty.  It deactivates the mark.

     The return value is not useful.

 -- User Option: transient-mark-mode
     This variable enables Transient Mark mode, in which every buffer-modifying primitive sets deactivate-mark.  The consequence of this is that commands that modify the buffer normally cause the mark to become inactive.

 -- Variable: deactivate-mark
     If an editor command sets this variable non-nil, then the editor command loop deactivates the mark after the command returns.

 -- Variable: mark-active
     The mark is active when this variable is non-nil.  This variable is always local in each buffer.

 -- Variable: activate-mark-hook
 -- Variable: deactivate-mark-hook
     These normal hooks are run, respectively, when the mark becomes active and when it becomes inactive.  The hook activate-mark-hook is also run at the end of a command if the mark is active and the region may have changed.

The Region
==========

The text between point and the mark is known as the region. Various functions operate on text delimited by point and the mark, but only those functions specifically related to the region itself are described here.

 -- Function: region-beginning
     This function returns the position of the beginning of the region (as an integer).  This is the position of either point or the mark, whichever is smaller.

     If the mark does not point anywhere, an error is signaled.

 -- Function: region-end
     This function returns the position of the end of the region (as an integer).  This is the position of either point or the mark, whichever is larger.

     If the mark does not point anywhere, an error is signaled.

Few programs need to use the region-beginning and region-end functions.  A command designed to operate on a region should instead use interactive with the r specification, so that the same function can be called with explicit bounds arguments from programs.  (see Interactive Codes.)